11.1 ポリライン・ポリマーカーにおける欠損値処理

データの中に欠損がある場合には, MATH1 の SYSLIB サブルーチンパッケージ にある GLLSET ルーチンで欠損値処理の指定に関する内部変数 'LMISS'.TRUE. にして, 欠損値処理を有効にします. 欠損値処理 の制御は SGPACK だけでなく DCL 全体で統一的に行われるために, 欠損値処 理に関する内部変数の管理はSGpGET/SGpSET ではなく GLpGET/GLpSET で行われています(pI, R, L または C).



このように指定すると, データの値が999.であるものは欠損値と見なして, こ れから見るような欠損値処理を行ないます. 欠損値999.が実際のデータ範囲に 入っていて, 別の値にしたい場合には, GLRSET ルーチンによって実数 の欠損値をあらわす内部変数 'RMISS' を変更します.

まず, MISS1プログラムを例に, ポリラインとポリマーカーのプリミティ ブで欠損値処理がどのように行なわれるか見てみましょう. 第3 章で用いた正弦関数のデータに欠損値 999.を埋め込みます. データの1/4のと ころでは3点連続して欠損値とし, 3/4のところでは, 有効な点が欠損値データ に挟まれて1点だけ孤立しているように与えます.

      PROGRAM MISS1

      PARAMETER( NMAX=40 )
      PARAMETER( PI=3.14159 )
      PARAMETER( XMIN=0., XMAX=4*PI, YMIN=-1., YMAX=1. )
      REAL X(0:NMAX), Y(0:NMAX)

      DT = XMAX/NMAX
      DO 10 N=0,NMAX
        X(N) = N*DT
        Y(N) = SIN(X(N))
   10 CONTINUE

      N1 = NMAX/4
      Y(N1-1) = 999.
      Y(N1  ) = 999.
      Y(N1+1) = 999.

      N2 = N1*3
      Y(N2-1) = 999.
      Y(N2+1) = 999.

      WRITE(*,*) ' WORKSTATION ID (I)  ? ;'
      CALL SGPWSN
      READ (*,*) IWS

      CALL GROPN( IWS )
      CALL GRFRM

*-- 欠損値処理なし ----
      CALL GRSWND( XMIN, XMAX, YMIN, YMAX )
      CALL GRSVPT(  0.1,  0.9,  0.7,  0.9 )
      CALL GRSTRN( 1 )
      CALL GRSTRF

      CALL SGPLU( NMAX+1, X, Y )

      CALL GRSWND( XMIN, XMAX, YMIN, YMAX )
      CALL GRSVPT(  0.1,  0.9,  0.5,  0.7 )
      CALL GRSTRN( 1 )
      CALL GRSTRF

      CALL SGSPMT( 3 )
      CALL SGPMU( NMAX+1, X, Y )

*-- 欠損値処理 ----
      CALL GLLSET( 'LMISS', .TRUE. )

      CALL GRSWND( XMIN, XMAX, YMIN, YMAX )
      CALL GRSVPT(  0.1,  0.9,  0.3,  0.5 )
      CALL GRSTRN( 1 )
      CALL GRSTRF

      CALL SGPLU( NMAX+1, X, Y )

      CALL GRSWND( XMIN, XMAX, YMIN, YMAX )
      CALL GRSVPT(  0.1,  0.9,  0.1,  0.3 )
      CALL GRSTRN( 1 )
      CALL GRSTRF

      CALL SGPMU( NMAX+1, X, Y )

      CALL GRCLS

      END
 
PROGRAM MISS1

\resizebox{10cm}{!}{\includegraphics{miss/miss1.eps}}
miss1.f: frame1

欠損値処理をしない(デフォルト)で SGPLUSGPMU のルーチン を呼んだ結果が上の2つです. 他のデータと比べて999.は非常に大きな値です から, ポリラインではほぼ真上に線を引いて最大作画範囲を飛び出しています. また, ポリマーカーでもこれらの点は作画範囲を飛び出してしまって描かれま せん.

GLLSET ルーチンで内部変数 'LMISS'.TRUE. にして, 欠損値処理を行なって描いた結果が下の2つです. ポリラインでは欠損値の前 後を線で結びません. 有効な点が1点だけ孤立している場合には, その点を結 ぶことができないので, そこには何も描かれません. また, ポリマーカーでは 欠損値の点にはマーカーを打ちません. この例では, ポリマーカーの結果はど ちらも同じですが, 欠損値を小さくして2.とすると違いは明らかです.