[ English | Japanese ] [ Gtool5 Documents | Gtool5 Tutorial ]

コマンドライン引数の解析

gtool5 には実行プログラムのコマンドライン引数を解析する するサブルーチンを提供するモジュール dc_args が用意され ています. これを用いるとプログラム実行時のオプション指定, ヘルプメッセージの表示などが可能になります.

例として, Fortran 90/95 汎用モジュール: 種別型パラメタの提供 で用いたサンプルプログラムに コマンドライン引数を与えるように修正したプログラムを示します (ソースコードはこちら). 赤字(カラーがでない場合はボールド)が dc_args に関係している箇所です. 関連して必要となる dc_types, dc_string, dc_message モジュールで提供されているデータ型とサブルーチンも use 文で参照しています.

!= Sample program for gtool_history/gtool5
!
! * 2007/06/27 M.Odaka
! * 2006/10/25 Y.Morikawa
! * 2003/08/21 M.Odaka
! * 2001/02/27 S.Takehiro
!
! Solving diffusion equation
! \[
!     du/dt = \kappa d^2 u/dx^2
! \]
! for giving values of $u$ at $x=[0,1]$.
!
program diffusion_7

  use gtool_history                                   ! Access module (モジュール指定)
  use dc_types, only : DP, STRING                   ! Access module (モジュール指定)
  use dc_message, only: MessageNotify               ! Access module (モジュール指定)
  use dc_string, only : StoA, StoI                  ! Access module (モジュール指定)
  use dc_args, only: ARGS, DCArgsOpen, DCArgsClose, DCArgsOption, &
    & DCArgsPutLine, DCArgsDebug, DCArgsHelp, DCArgsStrict
                                                    ! Access module (モジュール指定)

  integer, parameter     :: nx=30                   ! Grid number (グリッド数)
  integer, parameter     :: nt=200                  ! Time step number (時間ステップ数)
  integer, parameter     :: ndisp=10                ! Output interval (出力間隔)
  real(DP), parameter    :: dx=1.0/(nx-1)           ! Grid interval (グリッド間隔)
  real(DP), parameter    :: dt=0.0005               ! Time step (時間間隔)
  real(DP), dimension(nx):: x=(/(dx*(i-1),i=1,nx)/) ! X coordinate (座標変数)
  real(DP), dimension(nx):: temp                    ! Temperature (温度)
  real(DP), parameter    :: kappa=1.0               ! Diffusion coefficient (熱拡散係数)
  type(ARGS)             :: arg                     ! Command line argument (引数)
  logical                :: OPT_step                ! logical parameter (引数用論理変数)
  character(STRING)      :: VAL_step                ! Value of command line argument (引数の値)

  call DCArgsOpen(arg)                       ! Initialize variable 'arg'
                                             ! (引数の初期化) 
  call DCArgsOption(arg, StoA('-S', '--step'), OPT_step, VAL_step, &
    &         help="Specify time step (nt) [default value is 200]." )
                                             ! Set "-S/--step" option
                                             ! ("-S/--step" オプションの設定)

  call DCArgsDebug(arg)                      ! Set debug option
                                             ! (デバッグオプションの自動設定)
  call DCArgsHelp(arg)                       ! Set help option
                                             ! ヘルプオプションの自動設定
  call DCArgsStrict(arg)                     ! Set exception handling
                                             ! (無効なオプション指定時に警告表示)

  if (OPT_step) then
     nt = StoI(VAL_step)                     ! Set "nt" specified by command line argument 
                                             ! (引数の値を入力)

     call MessageNotify( "M", "diffusion_7", &
       &                 "Time step is %d", i=(/nt/) )
                                             ! Message dump
                                             ! (メッセージの出力)
  end if

  call DCArgsClose(arg)                      ! Finalize variable 'arg'
                                             ! (引数の使用終了)


  tinit = 0.0                                       ! 初期時刻設定

  temp = exp(-((x-0.5)/0.1)**2)                     ! 初期値設定

  call HistoryCreate( &                             ! ヒストリー作成
    & file='diffusion_7.nc', title='Diffusion equation', &
    & source='Sample program of gtool_history/gtool5',   &
    & institution='GFD_Dennou Club davis project',       &
    & dims=(/'x','t'/), dimsizes=(/nx,0/),               &
    & longnames=(/'X-coordinate','time        '/),       &
    & units=(/'m','s'/),                                 &
    & origin=real(tinit), interval=real(ndisp*dt) )

  call HistoryPut('x',x)                            ! 次元変数出力

  call HistoryAddVariable( &                        ! 変数定義
    & varname='temp', dims=(/'x','t'/), &
    & longname='temperature', units='K', xtype='double')

  call HistoryAddAttr('temp','gt_graph_tick_all',1)
  call HistoryAddAttr('temp','gt_graph_contour_spacing',(/0.0,1.0,0.01/))
  call HistoryAddAttr('temp','+gt_user_davis_kappa',kappa)

  call HistoryPut('temp',temp)                      ! 変数出力

  do it=1,nt
    temp(2:nx-1) = temp(2:nx-1) &                   ! 時間積分
      & + kappa*(temp(3:nx)-2*temp(2:nx-1)+temp(1:nx-2))/dx**2*dt

    if ( mod(it,ndisp) == 0 ) then
      call HistoryPut('temp',temp)                  ! 変数出力
    endif
  enddo

  call HistoryClose
  stop
end program diffusion_7

このプログラムではコマンドラインオプションで計算ステップ数を指定できる ようにしています. また, デバッグモードでの実行 ( Fortran90 汎用ライブラリ: (4) デバッグ補助 参照), ヘルプメッセージの出力もオプションで指定できます.

以下では dc_args モジュール サブルーチンが行っていることを大まかに説明します. ここで扱っていないサブルーチンの機能を含むより詳しい説明は リファレンスマニュアル を参照してください.

use dc_args
モジュールの使用を宣言します. Fortran90 メインプログラムの先頭にいれ ましょう. ここでは only 文を用いて必要なデータ型とブルーチンだけを参照します.
types(ARGS)
構造型 ARGS 変数の宣言文です. 引数情報は構造型 ARGS 変数に格納されます.
character(STRING)
種別型パラメタ STRING を用いた文字変数の宣言文です. 引数の値を格納する 文字型変数の種別型パラメタは, STRING にする必要があります. 種別型パラメタ STRING は dc_types モジュールで 提供されているので, メインプログラムの先頭部分で, use 文を用いて参照 します.
DCArgsOpen(arg)
構造型 ARGS 変数 arg の初期化を行います.
DCArgsOption(arg, options, flag, [value], [help])
オプション情報の登録と取得を行います. 引数の意味は以下の通りです.
DCArgsDebug(arg)
デバッグオプション -D および --debug を自動設定します.
DCArgsHelp(arg)
ヘルプオプション -H および --help を自動設定します. このサブルーチンを使う場合は事前に Option, Debug サブルーチンを呼ぶ 必要があります.
DCArgsStrict(arg, [severe])
オプションに与えられた文字列が Option サブルーチンで設定されていない 場合に警告を返します. 引数 [severe] を .true. にしておくと エラーを返しプログラムを強制終了します. このサブルーチンを使う場合は事前に Option, Debug, Help サブルーチンを 呼ぶ必要があります.
DCArgsClose(arg)
構造型 ARGS 変数 arg の使用を終了します.

$Id: dc_args.rd,v 1.3 2009-02-28 13:36:33 morikawa Exp $
gtool4 Development Group / GFD Dennou Staff dcstaff@gfd-dennou.org