#!/usr/bin/perl -w
#
# if_sndr_from.pl - 表書き発信者アドレス,
#                   および本文内の ``From:'' の後ろのアドレスが,
#                   引数で与えられたアドレス, またはドメイン
#                   に等しいか判断する.
#
# Copyright (C) 2003/11/07 Morikawa Yasuhiro <morikawa@ep.sci.hokudai.ac.jp>
#
#
# ■ 書式
#
#      ifsndr.pl  アドレス or ドメイン [アドレス or ドメイン...]
#
#
# ■ 説明
#
#      .qmail から呼び出されたばあい, 表書き発信者アドレスは
#      環境変数 SENDER で渡される (qmail-command(8)).
#      これが引数で与えられた 1 つ以上のアドレスのどれかと
#      等しければ 0 で終了し, どれとも等しくなければ 100 で終了する.
#      アドレス比較の際には，大文字小文字は区別されない.
#
#      ただし, 送られて来るメールに必ず環境変数 SENDER が指定
#      されているとは限らない. その場合を考え,
#      本文中の From: 行に書かれるアドレスも,
#      引数で与えられたアドレスと等しいかチェックする.
#
#      なお, 引数に「@」文字が入っていない場合, それはドメインと
#      見なされる. この場合, 引数と送信者アドレスの内の
#      ドメインとが比較され, 等しければ 0 で終了し,
#      どれとも等しくなければ 100 で終了する.
#      ドメイン比較の際には，大文字小文字は区別されない.
#
#      アドレスとドメインの同時指定も可能である.
#
#      ※ 余談だが, 環境変数 SENDER は, 大抵のメーラーの場合は,
#         From 行に書かれるべき送信者のアドレスが書かれる.
#         しかし, sendmail コマンド等で直接送られる場合は,
#         そのシステムが持つ「ドメイン名」を与えて来ることがある.
#         (例えば, ep.sci.hokudai.ac.jp ドメインを持つマシンから
#          メールを送ると, SENDER にはそのドメインが送られて来る).
#
#
# ■ dot-qmail の例 1
#      (特定の送信者のメールを``受け取りたい''場合)
#
#      |/var/qmail/bin/condredirect hoge-allow /xxx/if_sndr_from.pl xxx@yyy.zzz xxxx.yyyy
#
#      この例では，表書き発信者アドレスおよび``From:''の後に
#      書かれたアドレスが xxx@yyy.zzz あるいは xxxx.yyyy ドメイン
#      だった場合, hoge-allow に転送される.
#
#      表書き発信者アドレスおよび``From:''の後に書かれた
#      アドレスが xxx@yyy.zzz でなかったり, xxxx.yyyy ドメインで
#      なかったばあい, 配送されない.
#
#      これは, 特定の送信者のメールのみを許容したい場合の方法である.
#
#      condredirect(1), qmail-command(8) を参照せよ．
#
#
# ■ dot-qmail の例 2
#      (特定の送信者のメールを``別のアドレスへ送る''場合)
#
#      |/var/qmail/bin/condredirect hoge-deny /xxx/if_sndr_from.pl xxx@yyy.zzz xxxx.yyyy
#      &hogehoge@xxxxx.zz
#
#      この例では，表書き発信者アドレスおよび``From:''の後に
#      書かれたアドレスが xxx@yyy.zzz あるいは xxxx@yyyy.zzzz ドメイン
#      だったばあい, hoge-deny に転送される.
#
#      表書き発信者アドレスおよび``From:''の後に書かれた
#      アドレスが xxx@yyy.zzz でなかったり, xxxx.yyyy ドメインで
#      なかった場合, 次の行の配送命令が読まれ,
#      メールは hogehoge@xxxxx.zz へ転送される.
#
#      これは, 特定の送信者のメールのみを排除したい場合の方法である.
#      その場合, hoge-deny はそのためのアカウントということになる.
#
#      condredirect(1), qmail-command(8) を参照せよ．
#
#
# ■ 謝意
#
#      このプログラムは Kyoma TAKAHASHI さんにより作られた
#      ifsndr.pl <http://www.kyoma.net/tech/qmail/dot-qmail/ifsndr.html>
#      を参考に作成したものである.
#
#

#
# strict - 安全ではないコンストラクトを制限する Perl プラグマ
#
use strict ;

#
# 引数を @denylist へ
#
my (@denylist) = @ARGV ;

#
# SENDER アドレスを @senderev へ
#
my @senderev = ($ENV{'SENDER'}) ;

#
# SENDER アドレスに加え,
# 本文内の From: 行の後ろを取り出し,
# @senderev に加える.
#
while (<STDIN>) {
    # 最後の改行を削除
    chomp ($_);
    #
    # 行頭に from: (大文字, 小文字両方可) がついている
    # 行の, from:(スペース) より後ろの文字列を取り出し,
    # @senderev 配列の後ろに加える.
    #
    if ($_ =~ /^from:\s*(\S+)/i) {
	push(@senderev, $1) ;
    }
    print;         # $_ をそのまま print
    print "\n";    # chomp で取り除いた改行を復帰
}
print <STDIN>;     # 標準入力に文字列を返す

#
# @senderev の中身を小文字に.
#
my $send;
my @senderev_lowcase;
foreach $send (@senderev) {
    $send =~ tr/A-Z/a-z/ ;       # 小文字に
    push(@senderev_lowcase, $send) ;
}
@senderev = @senderev_lowcase;


#
# @senderev のどれかが @denylist のどれかとヒットするかチェック
#      1. ヒットしたらコード 0 を返す
#      2. ヒットしなかったらコード 100 を返す
#
my $add ;
my @domain ;
foreach $add (@denylist) {
    $add =~ tr/A-Z/a-z/ ;       # 小文字に
    #
    # $add (@denylist の1つ) 内に「@」が無い場合は,
    # ドメイン部をチェックするようにする.
    #
    if ($add !~ /@/){
	foreach $send (@senderev) {
	    @domain = split(/@/, $send, 2);
	    if ( $add eq $domain[1] ) {
	        exit 0 ;
	    }
	}
    } else {
	#
	# 「@」がある, つまりメールアドレスである場合,
	# アドレス全体ををチェックするようにする.
	#
	foreach $send (@senderev) {
	    if ( $add eq $send ) {
		exit 0 ;
	    }
	}
    }
}
exit 100 ;